Tumnus

Overdrive & distortion · Circuit · Silver

Wampler's mini Klon: the Centaur's circuit, germanium diodes after an op-amp, with part of the clean signal kept under the drive. Turning Gain up takes the clean part away.

An overdrive that does not take your amp’s place: it pushes it. With the gain low it thickens the sound and brings it forward, with that lift in the mids that gets a guitar through a mix. Turn the gain up and it growls, but part of the clean sound stays under the drive: chords keep their notes, the attack stays clear.

Its story

It starts in Boston with the Klon Centaur. Bill Finnegan spent years on it, after the sound of an amp played loud, adding gain without colouring the guitar. He sold it from late 1994, built by hand in a cast bronze enclosure with a sword-wielding centaur on it, the “horsie”. To keep it from being copied he buried the parts in resin; it did not stop much.

About 8,000 were made over some fifteen years. Waiting times grew to months, the margin was thin, and Finnegan stopped production in the late 2000s. He then released the KTR (2014), built in series, with a single addition: a buffered / true bypass switch. Meanwhile the used Centaur became a legend: around $2,000 in 2019, up to $20,000 in 2024. Jeff Beck, John Mayer, Joe Perry, Nels Cline, Matt Schofield and Ed O’Brien have played it.

That price gave rise to dozens of “klones”. Wampler’s is the Tumnus: a mini in October 2015, then the Tumnus Deluxe in November 2017, which adds adjustable Bass and Mids and a “Hot” mode. Germanium versions followed in 2023 and 2024.

The variant you play

It is the Klon Centaur circuit, the one the Tumnus reproduces. It was written by hand from the schematic traced by ElectroSmash, as J. Chowdhury reproduced it in his 2020 paper, and checked against that paper’s simulation of the gain stage. It is a tracing by others, not a document of Finnegan’s.

Three knobs, the Centaur’s: Gain, Treble and Output. Gain is the original’s dual potentiometer: one half sets the gain of the clipping stage, the other takes the clean sound away as the gain rises. The Tumnus Deluxe’s Bass, Mids and Hot mode are not in this circuit.

In the library it is the Tumnus, among the drives. The Tumnus Deluxe captures do not ship with the app: they are not ours.

What is not the pedal:

• the supply. The pedal makes 16.2 V and −8.6 V from 9 V with a charge pump, and 4.5 V with a divider; here they are ideal sources;
• the op-amps, a macro-model with a TL072’s figures;
• the diodes, 1N34A: the pedal’s are a germanium type nobody has identified;
• the footswitch, frozen with the effect on. The bypass path stays connected, as it is in the pedal.

The circuit

One line per part: its name, the nodes it connects, its value (1e4 is 10 kΩ, 1e-7 is 100 nF). A P line is a potentiometer (its two ends, then the wiper between them), and gang=Gain ties both halves of Gain to one knob. The X lines are the op-amps, described at the end.

Klon Centaur
* Written by hand for robine-spice from the schematic drawn by ElectroSmash
* ("Klon Centaur Analysis", electrosmash.com), as reproduced in J. Chowdhury,
* "A Comparison of Virtual Analog Modelling Techniques for Desktop and
* Embedded Implementations" (2020), and checked against the LTspice gain
* stage of that paper (github.com/jatinchowdhury18/KlonCentaur). Component
* names are the schematic's. It is a tracing of the pedal by others, not a
* document of its maker, and no pedal was measured for this netlist.
* What is not the pedal:
*   - the supply. The pedal makes 16.2 V and -8.6 V from 9 V with a charge
*     pump and 4.5 V with a divider; here the four are ideal sources;
*   - the op-amps, which are the macro-model the converted netlists use,
*     with a TL072's figures (3 MHz, 200 V/mV);
*   - the diodes, which are the 1N34A of the Distortion +, LiveSPICE's
*     model. The pedal's are an unidentified germanium type;
*   - the footswitch, frozen with the effect on. The bypass path stays, as
*     it does in the pedal: it loads the buffer and reaches the output
*     through R243.
* Gain is the pedal's dual potentiometer: one half sets the gain of the
* clipping stage, the other takes the clean signal away as the gain rises.
Vin in 0 DC 0

* Input buffer.
R1 in u1ap.c 1e4
C1 u1ap.c u1ap 1e-7
R2 u1ap bias 1e6
XU1A u1ap buf buf v9 0 opamp_tl072

* Bypass path.
C2 buf bypass.c 4.7e-6
R3 bypass.c 0 1e5
R4 bypass.c bypass 5.6e2
R243 bypass out 6.8e4

* Gain stage. PGainA has its wiper on the bias: what is above it shunts
* the input, what is below it is in the feedback leg.
C3 buf gain.in 1e-7
R6 gain.in u1bp 1e4
C5 gain.in u1bp 6.8e-8
PGainA leg bias u1bp 1e5 taper=lin pos=0.5 gang=Gain
R10 leg leg.b 2e3
R11 leg.b u1bn 1.5e4
C7 leg.b u1bn 8.2e-8
R12 u1bn u1bo 4.22e5
C8 u1bn u1bo 3.9e-10
XU1B u1bp u1bn u1bo v9 0 opamp_tl072
C9 u1bo clip.c 1e-6
R13 clip.c clip 1e3
D2 0 clip d_1n34a
D3 clip 0 d_1n34a
C10 clip clipped 1e-6
R16 clipped sum 4.7e4

* Clean path around the gain stage (ElectroSmash's "network 1").
R7 gain.in around 1.5e3
C16 around 0 1e-6
R19 around sum 1.5e4

* Clean path through the other half of Gain ("network 2").
R5 buf clean 5.1e3
C4 buf clean 6.8e-8
R8 clean bias 1.5e3
C6 clean clean.c 3.9e-7
R9 clean.c bias 1e3
PGainB bias blend clean 1e5 taper=lin pos=0.5 gang=Gain
C11 clipped blend.c 2.2e-9
R15 blend.c blend 2.2e4
R17 sum blend 2.7e4
C12 sum blend.d 2.7e-8
R18 blend.d blend 1.2e4

* Summing amplifier.
R20 sum summed 3.92e5
C13 sum summed 8.2e-10
XU2A bias sum summed vpos vneg opamp_tl072

* Treble.
R22 summed u2bn 1e5
R24 u2bn toned 1e5
R21 summed treble.a 1.8e3
PTreble treble.a treble.w treble.b 1e4 taper=lin pos=0.5
R23 treble.b toned 4.7e3
C14 treble.w u2bn 3.9e-9
XU2B bias u2bn toned vpos vneg opamp_tl072

* Output.
C15 toned level.c 4.7e-6
R25 level.c level 5.6e2
POutput level out 0 1e4 taper=lin pos=0.5
R28 out 0 1e5

Vbias bias 0 DC 4.5
V9 v9 0 DC 9
Vpos vpos 0 DC 16.2
Vneg vneg 0 DC -8.6

.subckt opamp_tl072 inp inn out vcc vee
Rin inp inn 1e12
Ggain 0 stage inp inn 2e2
Rstage stage 0 1e3
Cstage stage 0 1.0610329539459689e-5
Vhigh vcc top DC 2
Dhigh stage top opamp_clamp
Vlow bottom vee DC 2
Dlow bottom stage opamp_clamp
Gout 0 out stage out 1e-2
.ends
.model d_1n34a D(IS=2e-7 N=1.3e0)
.model opamp_clamp D(IS=8e-16 N=1)
.input Vin
.output out

Measured against

Eight captures of a Wampler Tumnus Deluxe by outmodedelectronics, in Normal mode, Treble at 5, Level at 6, and Gain from 2 to 10. Bass and Mids are at noon: Wampler says they do nothing there, which makes the Deluxe comparable with the Centaur circuit. These captures were given to us with no licence to share them: we name them, we do not distribute them.

The input level is the one the captures record: 11.5 dBu, that is 4.12 V peak.

Its grade

Silver, score 70. The maths is right (it follows ngspice at −52.8 dB at 48 kHz, −76.8 dB at 192 kHz), its three knobs behave, and it is close to the real pedal on a guitar take:

At Gain 5, 6 and 10 the response and the compression land within a dB of the captured pedal. The clipping is a germanium one: a pair of silicon diodes would compress about 6 dB later.

Six settings are close (Gain 3, 4, 5, 6, 7 and 10), enough for platinum; it is the score that holds the medal at silver, and what holds the score at 70 is Gain 2 and Gain 8. It is not the circuit: the Tumnus’s Gain knob does not follow the same law as the Centaur’s at those positions (at Gain 2, the circuit set one step lower recovers both the capture’s compression and its treble; at Gain 8, the capture behaves as the circuit does at full gain, under three different EQ settings). That is the measured pedal’s potentiometer, not a fault of the model, so the circuit was left as it is. One detail remains: at high level the captures show even harmonics around −35 dB that the symmetric circuit does not make; that is within the captures’ own error.

Sources: Klon Centaur (Wikipedia), Klon Centaur Analysis (ElectroSmash), J. Chowdhury, KlonCentaur, GuitarPedalX, the Tumnus family.